EXCEL: Contar fechas en el mes actual

Para contar las fechas en el mes actual, puede usar una fórmula basada en la función CONTAR.SI.CONJUNTO o SUMAPRODUCTO como se explica a continuación. En el ejemplo que se muestra arriba, la fórmula en E7 es:

=CONTAR.SI.CONJUNTO(dates,">="&FIN.MES(HOY(),-1)+1,dates,"<"&FIN.MES(HOY(),0)+1)

Donde "fechas" es el rango nombrado B5: B104.

Cómo funciona esta fórmula

En esencia, esta fórmula usa la función CONTAR.SI.CONJUNTO para contar fechas en un rango cuando son mayores o iguales que el primer día del mes actual, y menores que el primer día del mes siguiente. La función FIN.MES se usa para crear ambas fechas basadas en la fecha actual, que es proporcionada por la función HOY.

Para obtener el primer día del mes, utilizamos:

FIN.MES(HOY(),-1)+1

Aquí, la función FIN.MES devuelve el último día del mes anterior, al que se agrega 1 para obtener el primer día del mes actual.

Para obtener el último día del mes actual, FIN.MES se usa así:

FIN.MES(HOY(),0)+1

FIN.MES devuelve el último día del mes actual, al que se agrega 1 para obtener el primer día del mes siguiente.

Para contar fechas en el mes anterior:

=CONTAR.SI.CONJUNTO(dates,">="&FIN.MES(HOY(),-2)+1,dates,"<"&FIN.MES(HOY(),-1)+1) 

Para contar fechas en el próximo mes:

=CONTAR.SI.CONJUNTO(dates,">="&FIN.MES(HOY(),0)+1,dates,"<"&FIN.MES(HOY(),1)+1)

Alternativa SUMAPRODUCTO

También puede contar fechas en el mes anterior, actual y el próximo usando SUMAPRODUCTO de esta manera:

=SUMAPRODUCTO(N(TEXTO(FIN.MES(HOY(),-1),"mmyy")=TEXTO(rng,"mmyy")))
=SUMAPRODUCTO(N(TEXTO(HOY(),"mmyy")=TEXTO(rng,"mmyy")))
=SUMAPRODUCTO(N(TEXTO(FIN.MES(HOY(),1),"mmyy")=TEXTO(rng,"mmyy")))

Aquí, las fechas se introducen en la función TEXTO para obtener una cadena de mes y año, que se utiliza para comparar en una operación de matriz dentro de SUMAPRODUCTO. El resultado es una matriz de valores VERDADERO FALSO, donde VERDADERO representa fechas en el mes de interés.

La función N se usa para cambiar estos valores a unos y ceros, y SUMAPRODUCTO simplemente suma y devuelve la matriz.