EXCEL: Mínimo si múltiples criterios

Para obtener el valor mínimo en un conjunto de datos utilizando múltiples criterios (es decir, para obtener MIN SI), puede usar una fórmula de matriz basada en las funciones MIN y SI. En el ejemplo que se muestra, la fórmula en I6 es:

{=MIN(SI(color=G6,SI(item=H6,price)))}

Con un color de "rojo" y un elemento de "sombrero" el resultado es $ 8.00

Nota: Esta es una fórmula de matriz y debe ingresarse usando Ctrl + Shift + Enter

Cómo funciona esta fórmula

Este ejemplo utiliza los siguientes rangos con nombre: "color" = B6: B14, "elemento" = C6: C14 y "precio" = E6: E14. En el ejemplo, tenemos precios para artículos en varias regiones. El objetivo es encontrar el precio mínimo para un determinado color y artículo.

Esta fórmula usa dos funciones SI anidadas, envueltas dentro de MIN para devolver el precio mínimo usando dos criterios. Comenzando con la prueba lógica de la primera instrucción SI, color = G6, los valores en el color del rango nombrado (B6: B14) se comparan con el valor en la celda G6, "rojo". El resultado es una matriz como esta:

{VERDADERO;VERDADERO;VERDADERO;FALSO;FALSO;FALSO;FALSO;FALSO;FALSO}

En la prueba lógica para la segunda instrucción SI, elemento = H6, los valores en el elemento de rango nombrado (C6: C14) se comparan con el valor en la celda H6, "sombrero". El resultado es una matriz como esta:

{VERDADERO;VERDADERO;VERDADERO;VERDADERO;VERDADERO;VERDADERO;FALSO;FALSO;FALSO}

El "valor si es verdadero" para la segunda declaración SI, el rango con nombre "precios" (E6: E14), que es una matriz como esta:

{11;8;9;12;9;10;9;8;7}

Se devuelve un precio por cada artículo en este rango solo cuando el resultado de los dos primeros arreglos anteriores es VERDADERO para artículos en las posiciones correspondientes. En el ejemplo que se muestra, la matriz final dentro de MIN se ve así:

{11;8;9;FALSO;FALSO;FALSO;FALSO;FALSO;FALSO}

Tenga en cuenta que los únicos precios que "sobreviven" son aquellos en una posición donde el color es "rojo" y el artículo es "sombrero".

La función MIN devuelve el precio más bajo, ignorando automáticamente los valores FALSO.

Sintaxis alternativa usando lógica booleana

También puede usar la siguiente fórmula de matriz, que usa solo una función SI junto con la lógica booleana:

{=MIN(SI((color=G6)*(item=H6),price))}

La ventaja de esta sintaxis es que es posiblemente más fácil agregar criterios adicionales sin agregar funciones SI anidadas adicionales.

Con la función MINIFS

La función MINIFS, presentada en Excel 2016 a través de Office 365, está diseñada para devolver mínimos basados ​​en uno o más criterios, sin la necesidad de una fórmula de matriz. Con MINIFS, la fórmula en I6 se convierte en:

=MINIFS(price,color,G6,item,H6)