EXCEL: BUSCARX con múltiples criterios

Para usar BUSCARX con múltiples criterios, puede concatenar valores de búsqueda y matrices de búsqueda directamente en la fórmula. En el ejemplo que se muestra, la fórmula en H8 es:

=BUSCARX(H5&H6&H7,B5:B14&C5:C14&D5:D14,E5:E14)

BUSCARX devuelve $ 17.00, el precio de una gran camiseta roja.

Nota: BUSCARX puede manejar matrices de forma nativa; no es necesario ingresar con control + shift + enter.

Cómo funciona esta fórmula

Una de las ventajas de BUSCARX sobre CONSULTAV es que BUSCARX puede trabajar con matrices directamente, en lugar de requerir rangos en una hoja de trabajo. Esto hace posible ensamblar matrices en la fórmula e insertarlas en la función.

Trabajando un argumento a la vez, el valor de búsqueda se crea uniendo H5, H6 y H7 usando la concatenación:

=BUSCARX(H5&H6&H7

Esto da como resultado la cadena "T-shirtLargeRed".

La matriz de búsqueda se crea de manera similar, excepto que ahora estamos uniendo rangos:

=BUSCARX(H5&H6&H7,B5:B14&C5:C14&D5:D14

La matriz de retorno se suministra como un rango normal :, E5: E14:

=BUSCARX(H5&H6&H7,B5:B14&C5:C14&D5:D14,E5:E14

En esencia, estamos buscando el valor de búsqueda "T-shirtLargeRed" en datos como este:

lookup_array	result_array
T-shirtSmallRed	15
T-shirtMediumBlue	16
T-shirtLargeRed	17
HoodieSmallGray	28
HoodieMediumBlue	29
HoodieLargeBlack	30
HatMediumBlack	25
HatMediumGray	26
HatLargeRed	24
T-shirtLargeBlue	16

El modo de coincidencia predeterminado es exacto, y el modo de búsqueda predeterminado es la primera coincidencia, por lo que BUSCARX devuelve $ 17.00.

Con lógica booleana

Si bien la sintaxis explicada anteriormente funciona bien para la simple coincidencia de "igual a", también puede usar la lógica booleana para construir una fórmula como esta:

=BUSCARX(1,(B5:B14=H5)*(C5:C14=H6)*(D5:D14=H7),E5:E14)

Este es un enfoque más flexible porque la sintaxis se puede ajustar para usar otros operadores lógicos y otras funciones según sea necesario para búsquedas más complejas.