EXCEL: Diferencia mínima si no está en blanco

Para calcular la diferencia mínima entre dos conjuntos de valores, ignorando los casos en que cualquiera de los valores está en blanco, puede usar una fórmula de matriz basada en las funciones MIN y SI. En el ejemplo que se muestra, la fórmula en F4 es:

{=MIN(SI((B5:B12<>"")*(C5:C12<>""),B5:B12-C5:C12))}

que devuelve 115, el mínimo del costo de ventas, ignorando los casos en que cualquiera de los valores está en blanco.

Nota: esta es una fórmula de matriz y debe ingresarse con Control + Shift + Enter.

Cómo funciona esta fórmula

En el ejemplo que se muestra, el objetivo es calcular la diferencia mínima de ventas menos el costo, pero solo cuando se hayan ingresado ambos valores. Si cualquiera de los valores está en blanco, el resultado debe ignorarse. Para confirmar que ambos valores están disponibles, la función SI está configurada para usar lógica booleana con esta expresión:

(B5:B12<>"")*(C5:C12<>"")

Como cada rango contiene 8 celdas, el resultado de esta operación es una matriz como esta:

{1;1;1;0;1;1;0;0}

Esta matriz actúa como un filtro. En los casos en que el valor es 1, SI permite que los valores pasen a MIN. Los valores de diferencia reales se calculan con otra operación de matriz:

B5:B12-C5:C12

que genera este resultado:

{150;255;125;1100;150;115;-890;1025}

Después de evaluar la prueba lógica, la matriz que se pasa a la función MIN se ve así:

{150;255;125;FALSO;150;115;FALSO;FALSO}

Observe que el "valor de diferencia" para las filas donde Ventas o Costo están en blanco ahora es FALSO. La función MIN ignora automáticamente los valores FALSO y devuelve el mínimo de números restantes, 115.

Diferencia máxima ignorando espacios en blanco

Para devolver la diferencia máxima ignorando los valores en blanco, puede sustituir MAX por MIN:

{=MAX(SI((B5:B12<>"")*(C5:C12<>""),B5:B12-C5:C12))}

Esta fórmula funciona de la misma manera que se explicó anteriormente.

Con MINIFS y columna auxiliar

La función MINIFS se puede usar para resolver este problema, pero requiere el uso de una columna auxiliar con una fórmula como esta:

=B5-C5

Con la fórmula anterior en la columna D, MINIFS se puede usar así:

=MINIFS(D5:D12,B5:B12,"<>",C5:C12,"<>")

Esta no es una fórmula de matriz, y no necesita ser ingresada con control + shift + enter.