EXCEL: Coincidir valores que contienen texto específico con BUSCARX

Explicación

Para usar BUSCARX para hacer coincidir valores que contienen texto específico, puede usar comodines y concatenación. En el ejemplo que se muestra, la fórmula en F5 es:

=BUSCARX("*"&E5&"*",code,quantity,"no match",2)

donde el código (B5: B15) y la cantidad (C5: C15) se denominan rangos.

Cómo funciona esta fórmula

La función BUSCARX contiene soporte incorporado para comodines, pero esta característica debe habilitarse explícitamente configurando el modo de coincidencia en el número 2.
En el ejemplo que se muestra, BUSCARX está configurado para coincidir con el valor ingresado en la celda E5, que puede aparecer en cualquier lugar de los valores de búsqueda en B5: B15. La fórmula en F5 es:

=BUSCARX("*"&E5&"*",code,quantity,"no match",2) // returns 50

• valor de búsqueda: E5, con asteriscos (*) concatenados por delante y por detrás
• matriz de búsqueda: el código de rango con nombre (B5: B15)
• matriz de retorno: la cantidad de rango con nombre (C5: C15)
• si no se encuentra, la cadena "no coincide"
• modo de coincidencia: proporcionado como 2 (coincidencia de comodines)
• modo de búsqueda: no proporcionado. El valor predeterminado es 1 (primero al último)

Para que una coincidencia de tipo "contiene" automática, el asterisco comodín (*) se antepone y se agrega al valor en la celda E5 con concatenación:

"*"&E5&"*"

Después de la concatenación, la fórmula se convierte en:

=BUSCARX("*BCC*",code,quantity,"no match",2)

BUSCARX localiza la primera coincidencia que contiene "BCC" (050-BCC-123 en la fila 10) y devuelve el valor correspondiente de la matriz de retorno, 50.
Tenga en cuenta que BUSCARX no distingue entre mayúsculas y minúsculas, ingresando "bcc" en E5 devolverá el mismo resultado:

=BUSCARX("*bcc*",code,quantity,"no match",2) // returns 50

Vea a continuación una opción para configurar BUSCARX para una coincidencia entre mayúsculas y minúsculas.

Opción CONSULTAV

La fórmula CONSULTAV también es compatible con comodines cuando se establece la coincidencia exacta. La fórmula CONSULTAV equivalente para este ejemplo es:

=CONSULTAV("*"&E5&"*",B5:C15,2,0)

Explicación completa aquí.

Con HALLAR y ENCONTRAR

También es posible utilizar las funciones HALLAR y ENCONTRAR para realizar una coincidencia de tipo "contiene" con BUSCARX. Para una coincidencia entre mayúsculas y minúsculas (como en el ejemplo anterior), puede usar HALLAR de esta manera:

=BUSCARX(1,--ESNUMERO(HALLAR("BCC",code)),quantity,"no match",2)

Para una coincidencia entre mayúsculas y minúsculas, puede usar ENCONTRAR en su lugar:

=BUSCARX(1,--ESNUMERO(ENCONTRAR("BCC",code)),quantity,"no match",2)

Ambas opciones anteriores facilitan ampliar los criterios para incluir otras condiciones utilizando la lógica booleana.
La lógica de ESNUMERO + HALLAR se explica aquí.

Partidos múltiples

Si necesita múltiples coincidencias, vea la función FILTRAR.