EXCEL: BUSCARX reorganiza las columnas

Explicación

BUSCARX puede usarse para reordenar columnas, anidando un BUSCARX dentro de otro. En el ejemplo que se muestra, la fórmula en G9 es:

=BUSCARX(G8:J8,B4:E4,BUSCARX(G5,E5:E15,B5:E15))

Lo que devuelve una coincidencia en el valor en G5, con los 4 campos en una secuencia diferente.

Cómo funciona esta fórmula

Esta fórmula usa BUSCARX dos veces, al anidar un BUSCARX dentro de otro. El primer BUSCARX (interno) se utiliza para realizar una búsqueda de coincidencia exacta del valor en G5:

BUSCARX(G5,E5:E15,B5:E15)

• El valor de búsqueda proviene de la celda G5
• La matriz de búsqueda es E5: E15 (códigos)
• La matriz de retorno es B5: E15 (todos los campos)
• No se proporciona el modo de coincidencia y el valor predeterminado es 1 (coincidencia exacta)
• El modo de búsqueda no se proporciona y el valor predeterminado es 1 (primero al último)

El resultado es una coincidencia en "AX-160", devuelta como una matriz de los cuatro campos en el orden original:

{160,130,60,"AX-160"}

Este resultado se entrega directamente al segundo BUSCARX (externo) como argumento de matriz de retorno. El valor de búsqueda se proporciona como un rango que representa el nuevo orden de los campos, y la matriz de búsqueda es el rango que contiene el orden del nombre del campo original.

=BUSCARX(G8:J8,B4:E4,{160,130,60,"AX-160"})

• El valor de búsqueda es el rango G8: J8 (nuevo orden de campo)
• La matriz de búsqueda es el rango B4: E4 (antiguo orden de campo)
• La matriz de retorno es el resultado de la primera BUSCARX

Esta es la parte difícil. Estamos pasando múltiples valores de búsqueda, por lo que BUSCARX calculará internamente múltiples posiciones de coincidencia. Para cada valor en el nuevo rango de orden de campo, BUSCARX encontrará una posición dentro del rango de orden de campo anterior y usará esta posición para obtener un valor de la matriz de retorno (los valores devueltos por la primera función BUSCARX). El resultado es el resultado de búsqueda original con campos organizados en el nuevo orden.