EXCEL: Resaltar filas duplicadas

Excel contiene un preajuste incorporado para resaltar valores duplicados con formato condicional, pero solo funciona a nivel de celda. Si desea resaltar filas completas que están duplicadas, deberá usar su propia fórmula, como se explica a continuación.
Si desea resaltar filas duplicadas en un conjunto de datos sin clasificar, y no desea agregar una columna auxiliar, puede usar una fórmula que use la función CONTAR.SI.CONJUNTO para contar valores duplicados en cada columna de datos .
Por ejemplo, si tiene valores en las celdas B4: D11 y desea resaltar filas duplicadas completas, puede usar una fórmula bastante fea:

=CONTAR.SI.CONJUNTO($B$4:$B$11,$B4,$C$4:$C$11,$C4,$D$4:$D$11,$D4)>1

Rangos con nombre para una sintaxis más limpia

La razón por la cual la fórmula anterior es tan fea es que necesitamos bloquear completamente cada rango de columna, luego usamos una referencia mixta para probar cada celda en cada columna. Si crea rangos con nombre para cada columna en los datos: col_a, col_b y col_c, la fórmula se puede escribir con una sintaxis mucho más limpia:

=CONTAR.SI.CONJUNTO(col_b,$B4,col_c,$C4,col_d,$D4)>1

Cómo funciona esta fórmula

En la fórmula, CONTAR.SI.CONJUNTO cuenta el número de veces que cada valor en una celda aparece en su columna "padre". Por definición, cada valor debe aparecer al menos una vez, por lo que cuando el recuento> 1, el valor debe ser un duplicado. Las referencias se bloquean cuidadosamente para que la fórmula devuelva verdadero solo cuando las 3 celdas seguidas aparezcan más de una vez en sus columnas respectivas.
La opción de la columna auxiliar "engaña" al combinar todos los valores en una fila en una sola celda utilizando la concatenación. Luego CONTAR.SI simplemente cuenta la cantidad de veces que aparece este valor concatenado en la columna D.

Columna auxiliar + concatenación

Si no le importa agregar una columna auxiliar a sus datos, puede simplificar bastante la fórmula de formato condicional. En una columna auxiliar, concatene los valores de todas las columnas. Por ejemplo, agregue una fórmula en la columna E que se vea así:

=B4&C4&D4

Luego use la siguiente fórmula en la regla de formato condicional:

=CONTAR.SI($E$4:$E$11,$E4)>1

Esta es una regla mucho más simple, y puede ocultar la columna auxiliar si lo desea.
Si tiene una gran cantidad de columnas, puede usar la función TEXTJOIN (Excel 2016 365) para realizar la concatenación usando un rango:

=TEXTJOIN(",",VERDADERO,A1:Z1)

Luego puede usar CONTAR.SI como se indica arriba.

SUMAPRODUCTO

Si usa una versión de Excel anterior a 2007, puede usar SUMAPRODUCTO de esta manera:

=SUMAPRODUCTO((col_b=$B4)*(col_c=$C4)*(col_d=$D4))>1