EXCEL: Texto más frecuente

Para extraer el valor de palabra o texto que ocurre con mayor frecuencia en un rango, puede usar una fórmula basada en varias funciones INDICE, COINCIDIR y MODA.

En el ejemplo que se muestra, la fórmula en H5 es:

=INDICE(B5:F5,MODA(COINCIDIR(B5:F5,B5:F5,0)))

Cómo funciona esta fórmula

Trabajando de adentro hacia afuera, la función COINCIDIR hace coincidir el rango contra sí mismo. Es decir, le damos a la función COINCIDIR el mismo rango para el valor de búsqueda y la matriz de búsqueda (B5: F5).

Debido a que el valor de búsqueda contiene más de un valor (una matriz), COINCIDIR devuelve una matriz de resultados, donde cada número representa una posición. En el ejemplo que se muestra, la matriz se ve así:

{1,2,1,2,2}

Donde aparece "perro", vemos 2, y donde aparece "gato", vemos 1. Esto se debe a que la función COINCIDIR siempre devuelve la primera coincidencia, lo que significa que las apariciones posteriores de un valor dado devolverán la misma (primera) posición.

A continuación, esta matriz se alimenta a la función MODA. MODA devuelve el número más frecuente, que en este caso es 2. El número 2 representa la posición en la que encontraremos el valor más frecuente en el rango.

Finalmente, necesitamos extraer el valor mismo. Para esto, utilizamos la función INDICE. Para la matriz, usamos el rango de valores (B5: F5). El número de fila es proporcionado por MODA.

INDICE devuelve el valor en la posición 2, que es "perro".

Celdas vacías

Para tratar con celdas vacías, puede usar la siguiente fórmula de matriz, que agrega una declaración SI para probar celdas vacías:

{=INDICE(B5:F5,MODA(SI(B5:F5<>"",COINCIDIR(B5:F5,B5:F5,0))))}

Esta es una fórmula de matriz, y debe ingresarse con control + shift + enter.