EXCEL: SUMAPRODUCTO cuenta múltiples criterios O

Para contar las filas coincidentes con múltiples criterios O, puede usar una fórmula basada en la función SUMAPRODUCTO. En el ejemplo que se muestra, la fórmula en F10 es:

=SUMAPRODUCTO(ESNUMERO(COINCIDIR(B5:B11,{"A","B"},0))*
ESNUMERO(COINCIDIR(C5:C11,{"X","Y","Z"},0)))

Esta fórmula devuelve un recuento de filas donde la columna uno es A o B y la columna dos es X, Y o Z.

Cómo funciona esta fórmula

Trabajando de adentro hacia afuera, cada criterio se aplica con una construcción ESNUMERO + COINCIDIR separada. Para generar un recuento de filas en la columna uno donde el valor es A o B, usamos:

ESNUMERO(COINCIDIR(B5:B11,{"A","B"},0)

COINCIDIR genera una matriz de resultados que se ve así:

{1;2;#N/A;1;2;1;2}

y ESNUMERO convierte esta matriz en esta matriz:

{VERDADERO;VERDADERO;FALSO;VERDADERO;VERDADERO;VERDADERO;VERDADERO}

Para generar un recuento de filas en la columna dos donde el valor es X, Y o Z, usamos:

ESNUMERO(COINCIDIR(C5:C11,{"X","Y","Z"},0))

Entonces COINCIDIR devuelve:

{1;2;3;3;#N/A;1;2}

y ESNUMERO se convierte a:

{VERDADERO;VERDADERO;VERDADERO;VERDADERO;FALSO;VERDADERO;VERDADERO}

Estas dos matrices se multiplican juntas dentro de SUMAPRODUCTO, que convierte automáticamente los valores VERDADERO FALSO en 1 y 0 como parte de la operación matemática.

Entonces, para visualizar, el resultado final se deriva así:

=SUMAPRODUCTO({1;1;0;1;1;1;1}*{1;1;1;1;0;1;1})
=SUMAPRODUCTO({1;1;0;1;0;1;1})
=5

Con referencias de celda

El ejemplo anterior usa constantes de matriz codificadas, pero también puede usar referencias de celda:

=SUMAPRODUCTO(ESNUMERO(COINCIDIR(B5:B11,E5:E6,0))*ESNUMERO(COINCIDIR(C5:C11,F5:F7,0)))

Más criterios

Este enfoque se puede "ampliar" para manejar más criterios. Puedes ver un ejemplo en este desafío de fórmula.