EXCEL: Suma por mes ignora año

Para sumar datos por mes, ignorando el año, puede usar una fórmula basada en las funciones SUMAPRODUCTO y MES. En el ejemplo que se muestra, la fórmula en H6 es:

=SUMAPRODUCTO((MES(dates)=3)*amounts)

El resultado es un total de todas las ventas en marzo, ignorando el año.

Cómo funciona esta fórmula

Este conjunto de datos contiene más de 2900 registros, y la fórmula anterior usa dos rangos con nombre:

dates = B5:B2932
amounts =  E5:E2932

Dentro de la función SUMAPRODUCTO, la función MES se usa para extraer el número de mes para cada fecha en el conjunto de datos y compararlo con el número 3:

(MES(dates)=3)

Si suponemos un pequeño conjunto de datos con 3 fechas cada una en enero, febrero y marzo (en ese orden), el resultado sería una matriz que contiene nueve números como este:

{1;1;1;2;2;2;3;3;3}

donde cada número es el "número de mes" para una fecha. Cuando los valores se comparan con 3, el resultado es una matriz como esta:

{FALSO;FALSO;FALSO;FALSO;FALSO;FALSO;VERDADERO;VERDADERO;VERDADERO}

Esta matriz se multiplica por los valores de cantidad asociados con cada fecha de marzo. Si suponemos que las nueve cantidades son iguales a 100, la operación se ve así:

{0;0;0;0;0;0;1;1;1} * {100;100;100;100;100;100;100;100;100}

Observe que la operación matemática cambia los valores de VERDADERO FALSO en unos y ceros. Después de la multiplicación, tenemos una sola matriz en SUMAPRODUCTO:

=SUMAPRODUCTO({0;0;0;0;0;0;100;100;100})

Tenga en cuenta que las únicas cantidades supervivientes están asociadas con marzo, el resto son cero.

Finalmente, SUMAPRODUCTO devuelve la suma de todos los elementos: 300 en el ejemplo abreviado anterior y 25.521 en la captura de pantalla con datos reales.

Cuenta por mes ignorando año

Para obtener un conteo por mes ignorando el año, puede usar SUMAPRODUCTO de esta manera:

=SUMAPRODUCTO(--(MES(dates)=3))

Promedio por mes ignorando año

Para calcular y promediar por mes ignorando el año, combina las dos fórmulas SUMAPRODUCTO anteriores de esta manera:

=SUMAPRODUCTO((MES(dates)=3)*amounts)/SUMAPRODUCTO(--(MES(dates)=3))