EXCEL: Suma los valores superiores de n

Para sumar los valores superiores en un rango, puede usar una fórmula basada en la función K.ESIMO.MAYOR, envuelta dentro de la función SUMAPRODUCTO. En la forma genérica de la fórmula (arriba), rng representa un rango de celdas que contienen valores numéricos y N representa la idea del enésimo valor.

En el ejemplo, la celda activa contiene esta fórmula:

=SUMAPRODUCTO(K.ESIMO.MAYOR(B4:B13,{1,2,3}))

Cómo funciona esta fórmula

En su forma más simple, K.ESIMO.MAYOR devolverá el valor "enésimo más grande" en un rango. Por ejemplo, la fórmula:

=K.ESIMO.MAYOR(B4:B13, 2)

devolverá el segundo valor más grande en el rango B4: B13 que, en el ejemplo anterior, es el número 9.

Sin embargo, si proporciona una "constante de matriz" (por ejemplo, una constante en la forma {1,2,3}) a K.ESIMO.MAYOR como segundo argumento, K.ESIMO.MAYOR devolverá una matriz de resultados en lugar de un solo resultado Entonces, la fórmula:

=K.ESIMO.MAYOR(B4:B13,{1,2,3})

devolverá el 1er, 2do y 3er valor más grande en el rango B4: B13. En el ejemplo anterior, donde B4: B13 contiene los números 1-10, el resultado de K.ESIMO.MAYOR será la matriz {8,9,10}. SUMAPRODUCTO luego suma los números en esta matriz y devuelve un total, que es 27.

SUMA en lugar de SUMAPRODUCT

SUMAPRODUCTO es una función flexible que le permite utilizar referencias de celda para k dentro de la función K.ESIMO.MAYOR.

Sin embargo, si está utilizando una constante de matriz codificada como {1,2,3}, puede usar la función SUMA:

=SUMA(K.ESIMO.MAYOR(B4:B13,{1,2,3}))

Tenga en cuenta que debe ingresar esta fórmula como una fórmula de matriz si usa referencias de celda y no una constante de matriz para k dentro de K.ESIMO.MAYOR.

Cuando N se hace grande

Cuando N se hace grande, resulta tedioso crear la constante de matriz a mano: si desea sumar los 20 o 30 valores principales en una lista grande, escribir una constante de matriz con 20 o 30 elementos llevará mucho tiempo. En este caso, puede usar un acceso directo para construir la constante de matriz que usa las funciones FILA e INDIRECTO.

Por ejemplo, si desea SUMAR los 20 valores principales en un rango llamado "rng", puede escribir una fórmula como esta:

=SUMAPRODUCTO(K.ESIMO.MAYOR(rng,FILA(INDIRECTO("1:20"))))

Variable N

Con datos insuficientes, una N fija puede causar errores. En este caso, puede probar una fórmula como esta:

=SUMAPRODUCTO(K.ESIMO.MAYOR(rng,FILA(INDIRECTO("1:"&MIN(3,CONTAR(rng))))))

Aquí, usamos MIN con CONTAR para sumar los 3 valores principales, o el recuento de valores, si es menor que 3.