EXCEL: Redondear un número a n dígitos significativos

Si necesita redondear un número a un número dado (variable) de dígitos o cifras específicos, puede hacerlo con una fórmula elegante que use las funciones REDONDEAR y LOG10.
En el ejemplo que se muestra, la fórmula en D6 es la siguiente:

=REDONDEAR(B6,C6-(1+ENTERO(LOG10(ABS(B6)))))

Cómo funciona esta fórmula

Esta puede ser una fórmula intimidante si no tienes una buena formación en matemáticas, pero analicemos paso a paso.
Primero, cuando tiene una fórmula como esta donde una función (en este caso REDONDEAR) se ajusta a todas las demás, a menudo es útil trabajar desde afuera hacia adentro. Entonces, en el fondo, esta fórmula está redondeando el valor en B6 usando REDONDEAR función:

=REDONDEAR(B6,x)

Donde x es el número de dígitos significativos requeridos. La parte difícil de esta fórmula es calcular x. Esta es una variable, porque cambiará dependiendo del número que se está redondeando. x se calcula con este bit:

C6-(1+ENTERO(LOG10(ABS(B6))))

Esto parece complicado, así que veamos primero cómo debe funcionar la fórmula para los ejemplos dados. Recuerde con REDONDEAR que un número negativo de dígitos funciona en el lado izquierdo del decimal. Entonces, para redondear 1234567 a un número creciente de dígitos significativos, tendríamos:

=REDONDEAR(1234567,-6) = 1000000 // 1 sig. digit
=REDONDEAR(1234567,-5) = 1200000 // 2 sig. digits
=REDONDEAR(1234567,-4) = 1230000 // 3 sig. digits
=REDONDEAR(1234567,-3) = 1235000 // 4 sig. digits

Entonces, el problema principal es cómo calcular -6, -5, -4 y así sucesivamente dependiendo del número que estamos redondeando.
La clave es entender cómo se pueden expresar estos números usando exponentes, como en la notación científica:

=REDONDEAR(1234567,-6) = 1000000 = 1.0*10^6
=REDONDEAR(1234567,-5) = 1200000 = 1.2*10^6
=REDONDEAR(1234567,-4) = 1230000 = 1.23*10^6
=REDONDEAR(1234567,-3) = 1235000 = 1.235*10^6

Tenga en cuenta que el exponente es 6 en todos los casos, que se determina con este bit:

ENTERO(LOG10(ABS(B6)))

Entonces, el resto de la fórmula solo usa el valor de exponente calculado para calcular el número correcto para dar REDONDEAR dependiendo del número de dígitos significativos deseados:

=REDONDEAR(1234567,-6) // 1-(1+6) = -6
=REDONDEAR(1234567,-5) // 2-(1+6) = -5
=REDONDEAR(1234567,-4) // 3-(1+6) = -4
=REDONDEAR(1234567,-3) // 4-(1+6) = -3

Entonces, en resumen:

1. ABS convierte el valor en un valor absoluto (positivo)
2. LOG10 obtiene el exponente, en este caso 6 con un valor decimal
3. ENTERO recorta la parte decimal del exponente
4. La fórmula usa el exponente y los dígitos significativos suministrados para calcular el número correcto de dígitos para dar REDONDEAR
5. REDONDEAR redondea el número usando el número de dígitos suministrados