EXCEL: Ranking con sufijo ordinal

Para agregar un sufijo ordinal a un número (es decir, primero, segundo, tercero, etc.) puede usar una fórmula basada en la función ELEGIR para asignar el sufijo.
En el ejemplo que se muestra, la fórmula en C5 es:

=ELEGIR(B5,"st","nd","rd","th","th","th","th","th","th","th")

Cómo funciona esta fórmula

Los números ordinales representan la posición o rango en un orden secuencial. Normalmente se escriben con un sufijo de número + letra: primero, segundo, tercero, etc.
Para obtener un sufijo ordinal para un pequeño conjunto de números, puede usar la función ELEGIR de esta manera:

=ELEGIR(B5,"st","nd","rd","th","th","th","th","th","th","th")

Aquí ELEGIR simplemente toma un número de la columna B y usa ese número como índice para recuperar el sufijo correcto.

Una formula universal

Con un rango más amplio de números, no es práctico seguir agregando valores a ELEGIR. En ese caso, puede cambiar a una fórmula más complicada que use la función RESIDUO:

=SI(Y(RESIDUO(ABS(A1),100)>10,RESIDUO(ABS(A1),100)<14),"th",
ELEGIR(RESIDUO(ABS(A1),10)+1,"th","st","nd","rd","th","th","th","th","th","th"))

Esta fórmula primero usa RESIDUO con Y para "atrapar" el caso de números como 11, 12, 13, 111, 112, 113, etc. que tienen un sufijo no estándar con siempre "th". Todos los demás números usan los 10 valores de sufijo dentro de ELEGIR.
La función ABS se usa para manejar números negativos así como números positivos.

Concatenar sufijo a número

Puede concatenar (unir) el sufijo directamente utilizando cualquiera de las fórmulas anteriores. Por ejemplo, para agregar un sufijo ordinal a un número 1-10 en A1:

=A1&ELEGIR(A1,"st","nd","rd","th","th","th","th","th","th","th")

Pero tenga en cuenta que hacerlo cambiará el número a un valor de texto.