EXCEL: Obtener las primeras y últimas fechas del proyecto

Este ejemplo muestra cómo recuperar las primeras y últimas fechas asociadas con un proyecto. En el ejemplo que se muestra, las fórmulas en H5 e I5 son:

=MINIFS(data[Start],data[Project],G5) // earliest
=MAXIFS(data[End],data[Project],G5) // latest

donde "datos" es una tabla de Excel como se muestra, y los nombres de proyecto en la columna G coinciden con la columna B.
Nota: MINIFS y MAXIFS están disponibles solo en Excel 365 y Excel 2019. En otras versiones de Excel, puede usar una fórmula de matriz simple, como se explica a continuación.

Introducción

La tarea aquí es encontrar las fechas más tempranas y más recientes asociadas con un proyecto determinado. Las fechas más tempranas provienen de la columna Inicio, y las últimas fechas provienen de la columna Fin.
Es posible que sienta la tentación de utilizar una función de búsqueda como CONSULTAV, BUSCARX o INDICE y COINCIDIR. Sin embargo, dado que cada proyecto tiene más de una entrada, y las entradas no siempre se ordenan por fecha, esto se convierte en un desafío.
Un mejor enfoque es utilizar el proceso de eliminación: descartar fechas para otros proyectos y trabajar solo con las fechas que quedan.

Cómo funciona esta fórmula

La función MINIFS devuelve el valor numérico más pequeño que cumple con los criterios suministrados, y la función MAXIFS devuelve el valor numérico más grande que cumple con los criterios suministrados.
Al igual que CONTAR.SI.CONJUNTO y SUMAR.SI.CONJUNTO, estas funciones usan "pares" de rango / criterio para aplicar condiciones. Para ambas fórmulas, solo necesitamos una condición: el nombre del proyecto debe ser igual al nombre en la columna G:

data[Project],G5 // condition

Para obtener la fecha de inicio más temprana, utilizamos:

=MINIFS(data[Start],data[Project],G5) // earliest date

Aquí, MINIFS devuelve el valor mínimo en la columna Inicio donde el proyecto es igual a "Omega" (de la celda G5). Como las fechas de Excel son solo números, la fecha mínima es la misma que la fecha más temprana.
Para obtener la última fecha de finalización, utilizamos:

=MAXIFS(data[End],data[Project],G5) // latest date

Aquí, MAXIFS devuelve el valor máximo en la columna Fin donde el proyecto es igual a "Omega". Como arriba, el valor máximo es el mismo que la última fecha.

Alternativa de fórmula de matriz

Si no tiene MINIFS y MAXIFS, puede usar fórmulas de matriz simples, basadas en las funciones MIN y MAX, para obtener el mismo resultado. Para la fecha de inicio más temprana:

{=MIN(SI(data[Project]=G5,data[Start]))}

Para la última fecha de finalización:

{=MAX(SI(data[Project]=G5,data[End]))}

Nota: ambas fórmulas son fórmulas de matriz y deben ingresarse con control + shift + enter, en Excel 2019 o anterior. Con Excel 365, puede ingresar las fórmulas normalmente, ya que las fórmulas de matriz son nativas.
En ambos casos, la función SI se usa para "filtrar" valores de fecha como este:

SI(data[Project]=G5,data[End]) // filter dates by project

Cuando G5 es "Omega", SI devuelve la fecha de finalización. De lo contrario, SI devuelve FALSO. Como estamos probando todos los nombres de proyectos en la tabla al mismo tiempo, el resultado es una matriz de valores como este:

{43936;43983;43990;FALSO;FALSO;FALSO;FALSO;FALSO;FALSO;FALSO;FALSO;FALSO}

Los números de serie grandes son fechas de Excel asociadas con el proyecto Omega. Los otros valores son FALSO, ya que el proyecto no es Omega. Como MIN y MAX están programados para ignorar los valores lógicos VERDADERO y FALSO, solo funcionan con los valores restantes. MIN devuelve la fecha más pequeña (más temprana) y MAX devuelve la fecha más grande (más reciente).