EXCEL: Cuente valores únicos con criterios

Para contar valores únicos con una o más condiciones, puede usar la función CONTARA junto con UNICOS y FILTRAR. En el ejemplo que se muestra, la fórmula en H7 es:

=CONTARA(UNICOS(FILTRAR(B6:B15,C6:C15=H6)))

que devuelve 3, ya que hay tres nombres únicos en B6: B15 asociados con el proyecto Omega.
Nota: esta fórmula requiere fórmulas de matriz dinámica, disponibles solo en Excel 365. Con una versión anterior de Excel, puede usar fórmulas alternativas más complejas.

Cómo funciona esta fórmula

En esencia, esta fórmula usa la función UNICOS para extraer valores únicos y la función CONTARA para contar estos valores. La función FILTRAR se usa para aplicar criterios.
Trabajando de adentro hacia afuera, FILTRAR se usa para extraer solo los nombres asociados con el proyecto Omega:

FILTRAR(B6:B15,C6:C15=H6) // Omega names only

Esto da como resultado una serie de resultados como este:

{"Jim";"Jim";"Carl";"Sue";"Carl"}

A continuación, la función ÚNICA se usa para eliminar duplicados:

UNICOS({"Jim";"Jim";"Carl";"Sue";"Carl"})

lo que resulta en una nueva matriz como esta:

{"Jim";"Carl";"Sue"} // after UNICOS

Este conjunto se entrega directamente a la función CONTARA, que devuelve un recuento de todos los elementos del conjunto:

=CONTARA({"Jim";"Carl";"Sue"}) // returns 3

A diferencia de la función CONTAR, que solo cuenta números, CONTARA cuenta tanto el texto como los números. Como hay tres elementos en la matriz, CONTARA devuelve 3. Esta fórmula es dinámica y volverá a calcular inmediatamente si se modifican los datos de origen.

Cuente los espacios en blanco de ignorar únicos

Las celdas en blanco en la columna de nombre pueden hacer que aumente el recuento único porque FILTRAR incluirá el valor vacío en la matriz entregada a la función ÚNICA. Para ignorar las celdas en blanco o vacías en la columna B, puede ajustar la fórmula anterior de esta manera:

=CONTARA(UNICOS(FILTRAR(B6:B15,(C6:C15=H6)*(B6:B15<>""))))

Este es un ejemplo del uso de la lógica booleana para aplicar más de una condición. El enfoque se explica con más detalle aquí.

Cuenta única con múltiples criterios

Para contar valores únicos basados ​​en múltiples criterios, puede ampliar la lógica "incluir" dentro de FILTRAR. Por ejemplo, para contar nombres únicos para el proyecto Omega solo en junio, use:

=CONTARA(UNICOS(FILTRAR(B6:B15,(C6:C15=H6)*(D6:D15="june"))))

Para más detalles, vea este video de capacitación: Cómo filtrar con múltiples criterios.

Sin matrices dinámicas

Si está utilizando una versión anterior de Excel sin soporte de matriz dinámica, puede usar una fórmula más compleja. Para una discusión más general de las alternativas de matriz dinámica, vea: Alternativas a las fórmulas de matriz dinámica.