EXCEL: Cuente si la fila cumple con varios criterios internos

Para contar filas en una tabla que cumplan múltiples criterios, algunos de los cuales dependen de pruebas lógicas que funcionan a nivel de fila, puede usar la función SUMAPRODUCTO.

Contexto

Tienes una tabla que contiene los resultados de los partidos deportivos. Tiene cuatro columnas: equipo local, equipo visitante, puntaje del equipo local, puntaje del equipo visitante. Para un equipo determinado, desea contar solo los partidos (filas) donde el equipo ganó en casa. Es fácil contar partidos (filas) donde un equipo era el equipo local, pero ¿cómo se cuentan solo las victorias?

Este es un buen uso de la función SUMAPRODUCTO, que puede manejar operaciones de matriz (piense en operaciones que tratan con rangos) de forma nativa.

En el ejemplo que se muestra, la fórmula en la celda H5 es:

=SUMAPRODUCTO((B5:B10=G5)*(D5:D10>E5:E10))

Cómo funciona esta fórmula

La función SUMAPRODUCTO está programada para manejar matrices de forma nativa, sin requerir Control Shift Enter. Su comportamiento predeterminado es multiplicar los elementos correspondientes en una o más matrices juntas, luego sumar los productos. Cuando se le da una matriz única, devuelve la suma de los elementos en la matriz.

En este ejemplo, estamos usando dos expresiones lógicas dentro de un único argumento de matriz. Podríamos colocar cada expresión en un argumento separado, pero luego tendríamos que obligar a los valores lógicos VERDADERO FALSO a unos y ceros con otro operador.

Al usar el operador de multiplicación para multiplicar las dos matrices, Excel convertirá automáticamente los valores lógicos en unos y ceros.

Después de evaluar las dos expresiones lógicas, la fórmula se ve así:

=SUMAPRODUCTO(({FALSO;VERDADERO;FALSO;VERDADERO;FALSO;VERDADERO})*({VERDADERO;VERDADERO;VERDADERO;FALSO;VERDADERO;VERDADERO}))

Después de multiplicar las dos matrices, la fórmula se ve así:

=SUMAPRODUCTO({0;1;0;0;0;1})

Con solo una matriz restante, SUMAPRODUCTO simplemente suma los elementos en la matriz y devuelve la suma.