EXCEL: Contar celdas que contienen texto específico

Para contar las celdas que contienen cierto texto, puede usar la función CONTAR.SI con un comodín. En el ejemplo que se muestra, la fórmula en E5 es:

=CONTAR.SI(B5:B15,"*a*")

Cómo funciona esta fórmula

La función CONTAR.SI cuenta las celdas en un rango que cumple con los criterios. Por ejemplo, para contar el número de celdas en un rango que contienen "a" puede usar:

=CONTAR.SI(range,"a") // exact match

Sin embargo, tenga en cuenta que esta es una coincidencia exacta. Para ser contado, una celda debe contener exactamente "a". Si la celda contiene otros caracteres, no se contará.

Para el problema que se muestra, queremos contar las celdas que contienen texto específico, lo que significa que el texto podría estar en cualquier lugar de la celda. Para hacer esto, necesitamos usar el asterisco (*) como comodín. Por ejemplo, para contar celdas que contienen la letra "a" en cualquier lugar que usemos:

=CONTAR.SI(range,"*a*")

El asterisco en una fórmula significa "hacer coincidir cualquier número de caracteres, incluido cero", por lo que este patrón contará cualquier celda que contenga "a" en cualquier posición, con o sin otros caracteres a la izquierda o derecha. Todas las fórmulas utilizadas en el ejemplo siguen el mismo patrón:

=CONTAR.SI(B5:B15,"*a*") // contains "a"
=CONTAR.SI(B5:B15,"*2*") // contains "2"
=CONTAR.SI(B5:B15,"*-S*") // contains "-s"
=CONTAR.SI(B5:B15,"*x*") // contains "x"

Nota: CONTAR.SI no distingue entre mayúsculas y minúsculas.

Con una referencia de celda

Puede ajustar fácilmente esta fórmula para usar el contenido de otra celda para los criterios. Por ejemplo, si A1 contiene el texto que desea hacer coincidir, puede usar:

=CONTAR.SI(range,"*"&A1&"*")

Cuenta números específicos

La fórmula CONTAR.SI anterior no funcionará si está buscando un número particular y las celdas contienen datos numéricos. Esto se debe a que el comodín automáticamente hace que CONTAR.SI busque solo texto (es decir, busque "2" en lugar de solo 2). Debido a que un valor de texto nunca se encontrará en un número verdadero, CONTAR.SI devolverá cero.

Para contar un número específico en contenido numérico, puede usar una fórmula diferente basada en la función HALLAR y la función ESNUMERO de esta manera:

=SUMAPRODUCTO(--(ESNUMERO(HALLAR(text,range))))

En esta fórmula, el texto es el texto que está buscando y el rango es el rango de celdas que desea contar. Cuando HALLAR localiza una coincidencia, devolverá un número y la función ESNUMERO convertirá el número a un valor VERDADERO o FALSO. Debido a que estamos verificando más de una celda, el resultado será una matriz o valores VERDADERO y FALSO. El doble negativo se usa para convertir los valores VERDADERO y FALSO a 1s y 0s, y la función SUMAPRODUCTO devolverá la suma de la matriz como resultado final.

HALLAR trata automáticamente todos los números como texto, por lo que encontrará, por ejemplo, el 1 en el número 201. Además, no es necesario usar comodines para indicar la posición, porque HALLAR buscará automáticamente todo el texto en una celda.

Versión sensible a mayúsculas y minúsculas

Para un recuento sensible a mayúsculas y minúsculas, puede usar una fórmula basada en la función ENCONTRAR:

=SUMAPRODUCTO(--(ESNUMERO(ENCONTRAR(text,range))))

Aquí, la función ENCONTRAR se usa en lugar de HALLAR, porque ENCONTRAR distingue entre mayúsculas y minúsculas. En otros aspectos, la fórmula funciona como la fórmula ESNUMERO + ENCONTRAR descrita anteriormente.